M1 - Befundauskunft

Um die Befundauskunft des ausgewählten Patienten zu öffnen, wird eine Batch Datei erstellt und mit einer Geräteanbindung im M1 ausgelöst.

! ! ! ACHTUNG ! ! ! Für die M1 - GDT ist eine Lizenz erforderlich ! ! ! ACHTUNG ! ! !

Als Erstes wird das Batch Skript an einen lokalen Ort (wo jeder User Rechte hat zB. unter C:\AIS) abgelegt, die Batch Datei muss den Namen befundauskunft.bat haben.

Die Batch Datei nimmt sich die GDT Datei und liest den Vornamen, Nachnamen und das Geburtsdatum des Patienten aus. Diese Informationen nutzt er nun, um den Link zur labGate Webseite anzupassen. Anschließend wird die Webseite im Browser geöffnet.

Das Skript selber kann hier heruntergeladen werden.

Bitte passen Sie noch die labGate Webseite in der Batchdatei an!


@echo off & setlocal EnableDelayedExpansion
chcp 1252
set patgdtDatei=C:\AIS\OUT\patcmed.gdt
set labgateWebsite=https://demo.labgate.net
for /f "delims=*" %%i in ('findstr /r . "%patgdtDatei%"') do (
    set zeile=%%i
    set feldkennung=!zeile:~3,4!
    set inhalt=!zeile:~7!
    if /i "!feldkennung!" EQU "3101" set nachname=!inhalt!
    if /i "!feldkennung!" EQU "3102" set vorname=!inhalt!
    if /i "!feldkennung!" EQU "3103" set geburtsdatum=!inhalt!
)
set geburtsdatum=%geburtsdatum:~,2%.%geburtsdatum:~2,2%.%geburtsdatum:~4,4%
set nachname=%nachname: =+%
set vorname=%vorname: =+%
REM del /f /q "%patgdtDatei%"
set weblink=%labgateWebsite%/Result/All?query=%nachname%"%%2C+"%vorname%"+"%geburtsdatum%
start "" %weblink%

Um die Batch Datei über eine Geräteanbindung auslösen zu können, müssen zunächst zwei ini-Dateien bearbeitet werden.

Dazu bearbeiten Sie die m1geraet.ini im Ordner C:\COMPUMED\M1\PROJECT\GDT.

Bitte fügen Sie eine Zeile am Ende der ini-Datei hinzuschreiben folgendes hinein: Geraet$$$=labGate.ini;labGate

Die $ Zeichen ersetzen Sie bitte mit der nächst höheren Zahl.

Als Nächstes erstellen Sie bitte eine neue ini-Datei mit dem Name "labGate.ini".

Die ini-Datei kann hier heruntergeladen werden.


[Allgemein]
Prog = c:\AIS\befundauskunft.bat
XDTART = GDT
XDTVER = 2.1
DATKEN = pat
EXTENS = GDT

[Modi]
Modus001 = Anzeigen
Modus002 = Neuaufnahme
[Modus001]
Parameter = GDT $OUT$DAT
OutVerz = c:\AIS\OUT\
InVerz = c:\AIS\IN\
[Modus002]
Parameter = GDT $OUT$DAT
OutVerz = c:\AIS\OUT\
InVerz = c:\AIS\IN\
[Funktionen]
Funk001 = Befundauskunft
[Funk001]
Kennung = ALLG00
Modus001 = 6311
Modus002 = 6302
[6301]
Felder = 8000;8100;9218;3000;3101;3102;3103;3110;8402
[6302]
Felder = 8000;8100;9218;3000;3101;3102;3103;3110;3622;3623;8402
[6310]
Felder = 8000;8100;9218;3000;3101;3102;3103;3110;8402;6200
;;;; 11.07.2000 tad Felder = 8000+;8100;9218;3000;3101;3102;3103;3110;8402;8432;8439
[6311]
Felder = 8000;8100;9218;3000;3101;3102;3103;3110;8402;6200
;;;; 11.07.2000 tad Felder = 8000;8100;9218;3000;3101;3102;3103;3110;8402;8432;8439

Wenn Sie nun einen beliebigen Patienten öffnen und als neuen Karteikarteneintag ein "G" in das Typ-Feld ein und bestätigen es mit der ENTER Taste.

Es öffnet sich nun die Geräte-Auswahl. Hier wählen Sie bitte den Punkt "labGate" aus der Dropdown-Liste aus. Anschließend muss nur noch der grüne Haken betätigt werden.

Es wird nun eine GDT Datei erzeugt und die Batch Datei gestartet.

Beim Ausführen der Batch Datei, öffnet sich der Browser mit der Befundübersicht des zuvor im AIS aufgerufenen Patienten.